77 lines
2.1 KiB
Text
Executable file
77 lines
2.1 KiB
Text
Executable file
/* Tell the linker that we want an x86_64 ELF64 output file */
|
|
OUTPUT_FORMAT(elf64-x86-64)
|
|
|
|
/* We want the symbol kmain to be our entry point */
|
|
ENTRY(kmain)
|
|
|
|
/* Define the program headers we want so the bootloader gives us the right */
|
|
/* MMU permissions; this also allows us to exert more control over the linking */
|
|
/* process. */
|
|
PHDRS
|
|
{
|
|
limine_requests PT_LOAD;
|
|
text PT_LOAD;
|
|
rodata PT_LOAD;
|
|
data PT_LOAD;
|
|
}
|
|
|
|
SECTIONS
|
|
{
|
|
/* We want to be placed in the topmost 2GiB of the address space, for optimisations */
|
|
/* and because that is what the Limine spec mandates. */
|
|
/* Any address in this region will do, but often 0xffffffff80000000 is chosen as */
|
|
/* that is the beginning of the region. */
|
|
. = 0xffffffff80000000;
|
|
|
|
|
|
.text : {
|
|
text_start_ld = .;
|
|
*(.text .text.*)
|
|
text_end_ld = .;
|
|
} :text
|
|
|
|
/* Move to the next memory page for .limine_requests */
|
|
. = ALIGN(CONSTANT(MAXPAGESIZE));
|
|
|
|
/* Define a section to contain the Limine requests and assign it to its own PHDR */
|
|
.limine_requests : {
|
|
reqs_start_ld = .;
|
|
KEEP(*(.limine_requests_start))
|
|
KEEP(*(.limine_requests))
|
|
KEEP(*(.limine_requests_end))
|
|
reqs_end_ld = .;
|
|
} :limine_requests
|
|
|
|
/* Move to the next memory page for .rodata */
|
|
. = ALIGN(CONSTANT(MAXPAGESIZE));
|
|
|
|
.rodata : {
|
|
rodata_start_ld = .;
|
|
*(.rodata .rodata.*)
|
|
rodata_end_ld = .;
|
|
} :rodata
|
|
|
|
/* Move to the next memory page for .data */
|
|
. = ALIGN(CONSTANT(MAXPAGESIZE));
|
|
|
|
.data : {
|
|
data_start_ld = .;
|
|
*(.data .data.*)
|
|
} :data
|
|
|
|
/* NOTE: .bss needs to be the last thing mapped to :data, otherwise lots of */
|
|
/* unnecessary zeros will be written to the binary. */
|
|
/* If you need, for example, .init_array and .fini_array, those should be placed */
|
|
/* above this. */
|
|
.bss : {
|
|
*(.bss .bss.*)
|
|
*(COMMON)
|
|
data_end_ld = .;
|
|
} :data
|
|
|
|
/* Discard .note.* and .eh_frame* since they may cause issues on some hosts. */
|
|
/DISCARD/ : {
|
|
*(.eh_frame*)
|
|
*(.note .note.*)
|
|
}
|
|
}
|